Excel-uitleg

Weeknummer in Excel

Met ISO.WEEKNUMMER bereken je het Nederlandse weeknummer, en met een korte formule ook het juiste jaar – zonder fouten rond de jaarwisseling.

Weeknummer van een datum

Staat er in cel A2 een echte Excel-datum, dan gebruik je:

=ISO.WEEKNUMMER(A2)

Het resultaat is een getal van 1 tot en met 53 volgens ISO 8601. =WEEKNUMMER(A2;21) geeft hetzelfde resultaat. Het jaar krijg je niet terug.

Weeknummer met jaar

De donderdag van de week valt altijd in het juiste ISO-jaar:

="Week "&ISO.WEEKNUMMER(A2)&" "&JAAR(A2-WEEKDAG(A2;2)+4)

Voor 1 januari 2021 levert dat Week 53 2020 op. Als ISO-code: =JAAR(A2-WEEKDAG(A2;2)+4)&"-W"&TEKST(ISO.WEEKNUMMER(A2);"00").

Van weeknummer naar datum

Staat het jaar in B2 en het weeknummer in C2, dan vind je de maandag van die week met:

=DATUM(B2;1;4)-WEEKDAG(DATUM(B2;1;4);2)+1+(C2-1)*7

ISO.WEEKNUMMER of WEEKNUMMER?

`ISO.WEEKNUMMER(datum)`

Altijd de Nederlandse telling: de week begint op maandag en week 1 is de week met de eerste donderdag van het jaar.

`WEEKNUMMER(datum;type)`

Zonder type of met type 1 begint de week op zondag en is week 1 de week met 1 januari: de Amerikaanse telling. Alleen type 21 komt overeen met het ISO-weeknummer.

Weeknummer in Excel klopt niet?

WEEKNUMMER zonder type: wijkt in veel jaren een week af van het Nederlandse weeknummer.
JAAR(A2) als jaar van de week: geeft rond sommige jaarwisselingen ‘week 53 2021’ in plaats van ‘week 53 2020’.
Datum opgeslagen als tekst: zet die eerst om naar een echte datum.
Engelstalige Excel: daar heten de functies ISOWEEKNUM en WEEKNUM, en scheid je argumenten met een komma.

In Google Spreadsheets werkt ISOWEEKNUM(A2). Referentie: Microsoft-documentatie over ISO.WEEKNUMMER.